| ;------------------------------------------------------------------------------ | |
| ; | |
| ; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR> | |
| ; SPDX-License-Identifier: BSD-2-Clause-Patent | |
| ; | |
| ; Module Name: | |
| ; | |
| ; CopyMem.nasm | |
| ; | |
| ; Abstract: | |
| ; | |
| ; CopyMem function | |
| ; | |
| ; Notes: | |
| ; | |
| ;------------------------------------------------------------------------------ | |
| SECTION .text | |
| ;------------------------------------------------------------------------------ | |
| ; VOID * | |
| ; EFIAPI | |
| ; InternalMemCopyMem ( | |
| ; IN VOID *Destination, | |
| ; IN VOID *Source, | |
| ; IN UINTN Count | |
| ; ); | |
| ;------------------------------------------------------------------------------ | |
| global ASM_PFX(InternalMemCopyMem) | |
| ASM_PFX(InternalMemCopyMem): | |
| push esi | |
| push edi | |
| mov esi, [esp + 16] ; esi <- Source | |
| mov edi, [esp + 12] ; edi <- Destination | |
| mov edx, [esp + 20] ; edx <- Count | |
| lea eax, [esi + edx - 1] ; eax <- End of Source | |
| cmp esi, edi | |
| jae .0 | |
| cmp eax, edi ; Overlapped? | |
| jae @CopyBackward ; Copy backward if overlapped | |
| .0: | |
| mov ecx, edx | |
| and edx, 7 | |
| shr ecx, 3 ; ecx <- # of Qwords to copy | |
| jz @CopyBytes | |
| push eax | |
| push eax | |
| movq [esp], mm0 ; save mm0 | |
| .1: | |
| movq mm0, [esi] | |
| movq [edi], mm0 | |
| add esi, 8 | |
| add edi, 8 | |
| loop .1 | |
| movq mm0, [esp] ; restore mm0 | |
| pop ecx ; stack cleanup | |
| pop ecx ; stack cleanup | |
| jmp @CopyBytes | |
| @CopyBackward: | |
| mov esi, eax ; esi <- Last byte in Source | |
| lea edi, [edi + edx - 1] ; edi <- Last byte in Destination | |
| std | |
| @CopyBytes: | |
| mov ecx, edx | |
| rep movsb | |
| cld | |
| mov eax, [esp + 12] | |
| pop edi | |
| pop esi | |
| ret | |