| ;------------------------------------------------------------------------------ | |
| ; | |
| ; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR> | |
| ; SPDX-License-Identifier: BSD-2-Clause-Patent | |
| ; | |
| ; Module Name: | |
| ; | |
| ; SetMem.nasm | |
| ; | |
| ; Abstract: | |
| ; | |
| ; SetMem function | |
| ; | |
| ; Notes: | |
| ; | |
| ;------------------------------------------------------------------------------ | |
| DEFAULT REL | |
| SECTION .text | |
| ;------------------------------------------------------------------------------ | |
| ; VOID * | |
| ; InternalMemSetMem ( | |
| ; IN VOID *Buffer, | |
| ; IN UINTN Count, | |
| ; IN UINT8 Value | |
| ; ) | |
| ;------------------------------------------------------------------------------ | |
| global ASM_PFX(InternalMemSetMem) | |
| ASM_PFX(InternalMemSetMem): | |
| push rdi | |
| mov rdi, rcx ; rdi <- Buffer | |
| mov al, r8b ; al <- Value | |
| mov r9, rdi ; r9 <- Buffer as return value | |
| xor rcx, rcx | |
| sub rcx, rdi | |
| and rcx, 15 ; rcx + rdi aligns on 16-byte boundary | |
| jz .0 | |
| cmp rcx, rdx | |
| cmova rcx, rdx | |
| sub rdx, rcx | |
| rep stosb | |
| .0: | |
| mov rcx, rdx | |
| and rdx, 63 | |
| shr rcx, 6 | |
| jz @SetBytes | |
| mov ah, al ; ax <- Value repeats twice | |
| movdqa [rsp + 0x10], xmm0 ; save xmm0 | |
| movd xmm0, eax ; xmm0[0..16] <- Value repeats twice | |
| pshuflw xmm0, xmm0, 0 ; xmm0[0..63] <- Value repeats 8 times | |
| movlhps xmm0, xmm0 ; xmm0 <- Value repeats 16 times | |
| .1: | |
| movntdq [rdi], xmm0 ; rdi should be 16-byte aligned | |
| movntdq [rdi + 16], xmm0 | |
| movntdq [rdi + 32], xmm0 | |
| movntdq [rdi + 48], xmm0 | |
| add rdi, 64 | |
| loop .1 | |
| mfence | |
| movdqa xmm0, [rsp + 0x10] ; restore xmm0 | |
| @SetBytes: | |
| mov ecx, edx ; high 32 bits of rcx are always zero | |
| rep stosb | |
| mov rax, r9 ; rax <- Return value | |
| pop rdi | |
| ret | |